#!/bin/csh -f
set noglob
if ("$1" == "") then
   echo -n "File name(s) - may include wildcards: "
   set argv = $<
endif
foreach item ($argv)
   unset noglob
   set list=`ls -d $LAUE_MASTER/testdata/$item`
   foreach file ($list)
      if (-d $file == 0) then
         cp $file .
         set file=$file:t
         chmod +w $file
         if ($file:e == geasc) then
            echo "Translating $file to .ge1/.ge2 files"
            $LAUE_BIN/exchge << EOD > /dev/null
f
$file:r
$file:r
EOD
            echo "*Translation complete*"
         else if ($file:e == mtzasc) then
            echo "Translating $file to .mtz file"
            $LAUE_BIN/na4tomtz -n HKLIN $file HKLOUT $file:r.mtz >/dev/null
            echo "*Translation complete*"
         else if ($file:e == exch) then
            echo "Translating $file to .lcf file"
            $LAUE_BIN/exchange -n EXCHANGE $file LCF $file:r.lcf << EOD > /dev/null
TOLCF STANDARD
EOD
            echo "*Translation complete*"
         endif
      endif
   end
   set noglob
end